build.gradle

plugins {
  id "com.gradle.plugin-publish" version "0.11.0"
}

dependencies {
  implementation project(":provider")
  implementation gradleApi()
  implementation 'com.github.ajalt:mordant:1.2.1'
  implementation 'commons-io:commons-io:2.11.0'
  implementation "org.apache.commons:commons-lang3:${project.commonsLang3Version}"

  testImplementation "junit:junit:${project.junitVersion}"
  testImplementation 'org.mockito:mockito-core:2.28.2'
  testRuntimeOnly "org.junit.vintage:junit-vintage-engine:${project.junit5Version}"
  testImplementation('org.spockframework:spock-core:2.0-groovy-3.0') {
    exclude group: 'org.codehaus.groovy'
  }
}

// There is a Groovy version mismatch between GroovyDoc, Gradle and the project  
groovydoc {
  enabled = false
}

pluginBundle {
  website = 'https://github.com/DiUS/pact-jvm/tree/master/gradle'
  vcsUrl = 'https://github.com/DiUS/pact-jvm.git'
  description = 'Gradle plugin for verifying pacts against a provider.'
  tags = ['pact', 'cdc', 'consumerdrivencontracts', 'microservicetesting']

  plugins {
    pactProviderPlugin {
      id = 'au.com.dius.pact'
      displayName = 'Gradle Pact Provider plugin'
    }
  }
}

compileGroovy {
  dependsOn compileKotlin
  classpath = classpath.plus(files(compileKotlin.destinationDir))
}