build.gradle

/*
 * Copyright 2022 Thoughtworks, Inc.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

apply plugin: 'java'
apply from: "https://raw.githubusercontent.com/gocd/gocd-plugin-gradle-task-helpers/master/helper.gradle?_=${(int) (new Date().toInstant().epochSecond / 60)}"

gocdPlugin {
  id = 'com.thoughtworks.gocd.secretmanager.aws'
  pluginVersion = '1.1.0'
  goCdVersion = '20.9.0'
  name = 'AWS Secrets Manager based secrets plugin for GoCD'
  description = 'AWS Secrets Manager based secrets plugin for GoCD'
  vendorName = 'Thoughtworks, Inc.'
  vendorUrl = 'https://github.com/gocd/gocd-aws-based-secrets-plugin'

  githubRepo {
    owner = System.getenv('GITHUB_USER') ?: 'bob'
    repo = 'gocd-aws-based-secrets-plugin'
    token = System.getenv('GITHUB_TOKEN') ?: 'bad-token'
  }

  pluginProject = project

  prerelease = !"No".equalsIgnoreCase(System.getenv('PRERELEASE'))
  assetsToRelease = [project.tasks.findByName('jar')]
}

version = gocdPlugin.fullVersion(project)

repositories {
  mavenCentral()
  mavenLocal()
}

java {
  sourceCompatibility = JavaVersion.VERSION_11
  targetCompatibility = JavaVersion.VERSION_11
}

ext {
  deps = [
    gocdPluginApi: 'cd.go.plugin:go-plugin-api:24.4.0',
    awsSdk       : 'com.amazonaws:aws-java-sdk:1.12.780',
  ]

  versions = project.ext.deps.collectEntries { lib, libGav -> [lib, libGav.split(':').last()] }
}

dependencies {
  implementation group: 'cd.go.plugin.base', name: 'gocd-plugin-base', version: '0.0.8'
  compileOnly project.deps.gocdPluginApi
  implementation group: 'com.google.code.gson', name: 'gson', version: '2.11.0'
  implementation group: 'com.amazonaws', name: 'aws-java-sdk-secretsmanager', version: project.versions.awsSdk
  implementation group: 'com.amazonaws.secretsmanager', name: 'aws-secretsmanager-caching-java', version: '1.0.2'

  testImplementation platform('org.junit:junit-bom:5.11.4')
  testImplementation group: 'org.junit.jupiter', name: 'junit-jupiter-api'
  testImplementation group: 'org.junit.jupiter', name: 'junit-jupiter-params'
  testRuntimeOnly group: 'org.junit.jupiter', name: 'junit-jupiter-engine'
  testRuntimeOnly group: 'org.junit.platform', name: 'junit-platform-launcher'
  testImplementation group: 'org.assertj', name: 'assertj-core', version: '3.27.1'
  testImplementation group: 'org.mockito', name: 'mockito-core', version: '5.15.2'
  testImplementation group: 'org.jsoup', name: 'jsoup', version: '1.18.3'
  testImplementation project.deps.gocdPluginApi
  testImplementation group: 'org.skyscreamer', name: 'jsonassert', version: '1.5.3'
  testImplementation 'uk.org.webcompere:system-stubs-jupiter:2.1.7'
}


test {
  useJUnitPlatform()
}

jar {
  from(configurations.runtimeClasspath) {
    into "lib/"
  }
}