-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathoo2teilite.xsl
1284 lines (1109 loc) · 53.5 KB
/
oo2teilite.xsl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
<?xml version="1.0" encoding="UTF-8"?>
<!--
# The Contents of this file are made available subject to the terms of
# the GNU Lesser General Public License Version 2.1
# Authors:
# Gerrit Imsieke, Ralph Krüger, le-tex publishing services GmbH, Leipzig
# http://www.le-tex.de/
# Funded by Yanus Verlag GmbH, Hamburg
# http://www.yanus.de/
# GNU Lesser General Public License Version 2.1
# =============================================
# Copyright (C) 2009 le-tex publishing services GmbH
#
# This library is free software; you can redistribute it and/or
# modify it under the terms of the GNU Lesser General Public
# License as published by the Free Software Foundation; either
# version 2.1 of the License, or (at your option) any later version.
#
# This library is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
# Lesser General Public License for more details.
#
# You should have received a copy of the GNU Lesser General Public
# License along with this library; if not, write to the Free Software
# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
-->
<!DOCTYPE xsl:stylesheet [
<!-- Introductory notes:
Amongst others, this export filter implements the generation of marginal notes containing numbers.
These numbers can be used to reference the relating parts of the text.
Most commonly such a unit of text is a single para, but some other text elements get numbers too (e.g., headers, tables, ...).
Footnotes and their child elements are special insofar as they get numbered separately.
-->
<!-- elements matching this XPath expression are considered to be notes (footnotes and other ones, e.g. comments),
whose content will not be treated as part of the main text body (as far as numbering is concerned) -->
<!ENTITY note "tei:note">
<!-- elements matching this XPath expression are considered to be footnotes, whose content will be numered seperately -->
<!ENTITY footnote "tei:note[@type='footnote']">
<!-- TEI elements which are destined for getting a marginal number;
please note that note-elements and their children are numbered separately (see below) -->
<!ENTITY numberedMainTextElements
" /tei:TEI/tei:text/tei:front/tei:titlePage/tei:docTitle
| /tei:TEI/tei:text/tei:front/tei:titlePage/tei:docAuthor
| /tei:TEI/tei:text/tei:body//tei:div/tei:head[not( ancestor::¬e; or . = '')]
| /tei:TEI/tei:text/tei:body//tei:lg[not( ancestor::¬e;)]
| /tei:TEI/tei:text/tei:body//tei:quote[not( ancestor::¬e;)]
| /tei:TEI/tei:text/tei:body//tei:p[not( ancestor::¬e; or ancestor::tei:table or . = '')]
| /tei:TEI/tei:text/tei:body//tei:p/tei:table[not( ancestor::¬e;)]
| /tei:TEI/tei:text/tei:body//tei:div[@type eq 'letter']/tei:opener
| /tei:TEI/tei:text/tei:body//tei:div[@type eq 'letter']/tei:closer
| /tei:TEI/tei:text/tei:body//tei:table
"
>
<!-- TEI elements within footnotes which are destined for getting a number, i.e. represent a piece of text of reasonable size -->
<!-- We expect all text nodes, which are "decendants" of &footnote;, to be embedded in tei:p (or another parent element listed below). -->
<!ENTITY numberedFootnoteDescendant
" *[ self::tei:p[normalize-space( string-join( .//text(), ''))]
| self::tei:div/tei:head
| self::tei:lg
| self::tei:table
| self::tei:quote
]
"
>
<!-- TEI elements which are not destined for getting a number, i.e.:
(1) parts of the tree, which never get a number
(2) all descendants of &numberedMainTextElements; and &footnote;//&numberedFootnoteDescendant; except of <p> (because this may, e.g., contain a <table>/<quote> and so on
(3) elements which are not covered by rule (2) (e.g. the descendants of <p>, which do not get a number)
-->
<!ENTITY unnumberedElements
" (: case (1) :)
/tei:TEI/tei:teiHeader | /tei:TEI/tei:teiHeader//* (: in order to be able to use the expression in match-patterns, you must not use the descencdant-or-self-axis here :)
| *[ancestor::tei:note[@type='internal']]
(: case (2) :)
| /tei:TEI/tei:text/tei:front/tei:titlePage/tei:docTitle//*
| /tei:TEI/tei:text/tei:front/tei:titlePage/tei:docAuthor//*
| /tei:TEI/tei:text/tei:front/tei:titlePage/tei:docDate
| /tei:TEI/tei:text/tei:body//tei:div/tei:head//*[not( ancestor-or-self::&footnote;)]
| /tei:TEI/tei:text/tei:body//tei:table//*
(: case (2) with restrictions :)
| /tei:TEI/tei:text/tei:body//tei:lg/tei:l
(: case (3) :)
| //tei:hi
| //tei:emph
"
>
<!-- Processing modes where the default transformation will be identity -->
<!ENTITY catchAllModes
"resolve-styles
group-styles
clean-group-styles
exclude
hierarchize
verse
letter
main
join-segs
anonymous-divs
add-linear-numbering
splitParas_reassignRandnummern
add-subnumbering-for-split-paras
gloss"
>
]>
<xsl:stylesheet
version="2.0"
office:class="text"
office:version="1.2"
xmlns="http://www.tei-c.org/ns/1.0"
xmlns:saxon="http://saxon.sf.net/"
xmlns:letex="http://www.le-tex.de/namespace"
xmlns:chart="urn:oasis:names:tc:opendocument:xmlns:chart:1.0"
xmlns:config="urn:oasis:names:tc:opendocument:xmlns:config:1.0"
xmlns:dc="http://purl.org/dc/elements/1.1/"
xmlns:dom="http://www.w3.org/2001/xml-events"
xmlns:dr3d="urn:oasis:names:tc:opendocument:xmlns:dr3d:1.0"
xmlns:draw="urn:oasis:names:tc:opendocument:xmlns:drawing:1.0"
xmlns:field="urn:openoffice:names:experimental:ooo-ms-interop:xmlns:field:1.0"
xmlns:fo="urn:oasis:names:tc:opendocument:xmlns:xsl-fo-compatible:1.0"
xmlns:form="urn:oasis:names:tc:opendocument:xmlns:form:1.0"
xmlns:grddl="http://www.w3.org/2003/g/data-view#"
xmlns:math="http://www.w3.org/1998/Math/MathML"
xmlns:meta="urn:oasis:names:tc:opendocument:xmlns:meta:1.0"
xmlns:number="urn:oasis:names:tc:opendocument:xmlns:datastyle:1.0"
xmlns:of="urn:oasis:names:tc:opendocument:xmlns:of:1.2"
xmlns:office="urn:oasis:names:tc:opendocument:xmlns:office:1.0"
xmlns:ooo="http://openoffice.org/2004/office"
xmlns:oooc="http://openoffice.org/2004/calc"
xmlns:ooow="http://openoffice.org/2004/writer"
xmlns:rdfa="http://docs.oasis-open.org/opendocument/meta/rdfa#"
xmlns:rpt="http://openoffice.org/2005/report"
xmlns:script="urn:oasis:names:tc:opendocument:xmlns:script:1.0"
xmlns:style="urn:oasis:names:tc:opendocument:xmlns:style:1.0"
xmlns:svg="urn:oasis:names:tc:opendocument:xmlns:svg-compatible:1.0"
xmlns:table="urn:oasis:names:tc:opendocument:xmlns:table:1.0"
xmlns:tei="http://www.tei-c.org/ns/1.0"
xmlns:text="urn:oasis:names:tc:opendocument:xmlns:text:1.0"
xmlns:xforms="http://www.w3.org/2002/xforms"
xmlns:xhtml="http://www.w3.org/1999/xhtml"
xmlns:xlink="http://www.w3.org/1999/xlink"
xmlns:xsd="http://www.w3.org/2001/XMLSchema"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
exclude-result-prefixes="chart config dc dom dr3d draw field fo form grddl letex math meta number of office ooo oooc ooow rdfa rpt saxon script style svg table tei text xforms xhtml xlink xsd xsi xsl"
>
<xsl:output
method="xml"
encoding="UTF-8"
indent="no"
doctype-public="-//TEI//DTD TEI Lite 1.0//EN"
doctype-system="http://www.tei-c.org/release/xml/tei/custom/schema/dtd/teilite.dtd"
saxon:suppress-indentation="head p l"
use-character-maps="quot"
/>
<xsl:character-map name="quot">
<xsl:output-character character=""" string="&#34;"/>
</xsl:character-map>
<!-- customize me -->
<xsl:variable name="heading-markup" select="('Heading 1', 'Heading 2', 'Heading 3', 'Heading 4')"/>
<letex:style-mapping>
<letex:style att="style-name" attval="Y: Hervorhebung Kursiv" elt="seg" map="hi" />
<letex:style att="style-name" attval="Emphasis" elt="seg" map="hi" />
<letex:style att="style-name" attval="Footnote" elt="p" map="" />
<letex:style att="style-name" attval="Standard" elt="p" map="" />
</letex:style-mapping>
<!-- /customize me -->
<xsl:param name="debug" />
<xsl:function name="letex:map-style" as="xsd:string?">
<xsl:param name="elt" as="xsd:string" />
<xsl:param name="att" as="xsd:string" />
<xsl:param name="attval" as="xsd:string" />
<xsl:value-of
select="document('')//letex:style-mapping/letex:style[
(@att eq $att)
and ($attval = (if ($att eq 'style-name') then letex:quote-style-name($attval) else $attval))
and (@elt = $elt)
]/@map" />
</xsl:function>
<!-- PROCESSING PIPELINE: -->
<xsl:variable name="resolve-styles">
<xsl:apply-templates select="/" mode="resolve-styles"/>
</xsl:variable>
<xsl:variable name="group-styles">
<xsl:apply-templates select="$resolve-styles" mode="group-styles"/>
</xsl:variable>
<xsl:variable name="clean-group-styles">
<xsl:apply-templates select="$group-styles" mode="clean-group-styles"/>
</xsl:variable>
<xsl:variable name="hierarchize">
<TEI>
<teiHeader>
<fileDesc>
<titleStmt>
<title></title>
<author></author>
</titleStmt>
<publicationStmt>
<distributor>
<address>
<addrLine>
<name type="organisation"></name>
</addrLine>
<addrLine>
<name type="place"></name>
</addrLine>
<addrLine></addrLine>
</address>
</distributor>
<idno type="book"></idno>
<date></date>
<pubPlace></pubPlace>
<publisher></publisher>
</publicationStmt>
<sourceDesc>
<p></p>
</sourceDesc>
</fileDesc>
</teiHeader>
<text>
<body>
<xsl:choose>
<xsl:when test="$clean-group-styles/office:document/office:body/office:text/text:h/@text:outline-level">
<xsl:sequence select="letex:hierarchize-by-outline($clean-group-styles/office:document/office:body/office:text/*, min($clean-group-styles/office:document/office:body/office:text/text:h/@text:outline-level))" />
</xsl:when>
<xsl:otherwise>
<xsl:sequence select="letex:hierarchize($clean-group-styles/office:document/office:body/office:text/*, $heading-markup)" />
</xsl:otherwise>
</xsl:choose>
</body>
</text>
</TEI>
</xsl:variable>
<xsl:variable name="verse">
<xsl:apply-templates select="$hierarchize" mode="verse"/>
</xsl:variable>
<xsl:variable name="letter">
<xsl:apply-templates select="$verse" mode="letter"/>
</xsl:variable>
<xsl:variable name="main">
<xsl:apply-templates select="$letter" mode="main"/>
</xsl:variable>
<!-- <xsl:variable name="join-segs"> -->
<!-- <xsl:apply-templates select="$main" mode="join-segs"/> -->
<!-- </xsl:variable> -->
<xsl:variable name="anonymous-divs">
<xsl:apply-templates select="$main" mode="anonymous-divs"/>
</xsl:variable>
<xsl:variable name="add-linear-numbering">
<xsl:apply-templates select="$anonymous-divs" mode="add-linear-numbering"/>
</xsl:variable>
<xsl:variable name="add-subnumbering-for-split-paras">
<xsl:apply-templates select="$add-linear-numbering" mode="add-subnumbering-for-split-paras"/>
</xsl:variable>
<!-- Some people dislike this brute-force, sequential processing. For good reasons (waste of memory,
lack of elegance, reliance on a default catch-all identity transformation).
But this separation of concerns (one concern per processing mode) helps you keep the code modular
in cases where an external chaining of transformations isn't practicable, where a "closed form"
representation of all rules in a single mode is too complex or where an intelligent processing
of subtrees in adequate modes would be too – ehm – intelligent.
Of course it makes sense to process only a subtree for which a certain mode makes sense in that
mode, in contrast to processing the whole document in that mode. But you must admit that, for
debugging purposes, it's nice to be able to export the whole document as it looks before being
processed in a certain mode. Therefore the brute-force, global-variable, identity-default
transformations.
-->
<!-- INVOCATION: -->
<xsl:template match="/">
<xsl:if test="boolean($debug)">
<xsl:result-document href="debug.05.resolve-styles.xml">
<xsl:sequence select="$resolve-styles"/>
</xsl:result-document>
<xsl:result-document href="debug.10.clean-group-styles.xml">
<xsl:sequence select="$clean-group-styles"/>
</xsl:result-document>
<xsl:result-document href="debug.20.hierarchize.xml">
<xsl:sequence select="$hierarchize"/>
</xsl:result-document>
<xsl:result-document href="debug.30.letter.xml">
<xsl:sequence select="$letter"/>
</xsl:result-document>
<xsl:result-document href="debug.40.main.xml">
<xsl:sequence select="$main"/>
</xsl:result-document>
<xsl:result-document href="debug.50.anonymous-divs.xml">
<xsl:sequence select="$anonymous-divs"/>
</xsl:result-document>
<xsl:result-document href="debug.60.add-linear-numbering.xml">
<xsl:sequence select="$add-linear-numbering"/>
</xsl:result-document>
<xsl:result-document href="debug.62.add-subnumbering-for-split-paras.xml">
<xsl:sequence select="$add-subnumbering-for-split-paras"/>
</xsl:result-document>
</xsl:if>
<xsl:copy-of select="$add-subnumbering-for-split-paras" />
</xsl:template>
<!-- HEADING HIERARCHIES -->
<!-- Case A: No outline levels are specified in the document; headings are plain paragraphs with certain markup: -->
<xsl:function name="letex:hierarchize" as="node()*">
<xsl:param name="nodes" as="node()*" />
<xsl:param name="heading-markup" as="xsd:string*" />
<xsl:choose>
<xsl:when test="count($heading-markup) eq 0">
<xsl:sequence select="$nodes" />
</xsl:when>
<xsl:otherwise>
<xsl:variable name="new-heading-markup" select="letex:topmost-heading-markup($nodes, $heading-markup)" />
<xsl:choose>
<xsl:when test="count($new-heading-markup) gt 0">
<xsl:for-each-group select="$nodes" group-starting-with="*[letex:satisfies-heading-markup(., $new-heading-markup[1])]">
<xsl:choose>
<xsl:when test="letex:satisfies-heading-markup(current-group()[1], $new-heading-markup[1])">
<xsl:text>
</xsl:text>
<div type="{replace($new-heading-markup[1], '\s+', '_')}">
<!-- <xsl:copy-of select="current-group()[1]/@*" /> -->
<head>
<xsl:copy-of select="current-group()[1]/node()" />
</head>
<xsl:sequence select="letex:hierarchize(current-group()[position() gt 1], $new-heading-markup[position() gt 1])" />
</div>
</xsl:when>
<xsl:otherwise>
<xsl:sequence select="letex:hierarchize(current-group(), $new-heading-markup[position() gt 1])" />
</xsl:otherwise>
</xsl:choose>
</xsl:for-each-group>
</xsl:when>
<xsl:otherwise>
<xsl:sequence select="$nodes" />
</xsl:otherwise>
</xsl:choose>
</xsl:otherwise>
</xsl:choose>
</xsl:function>
<xsl:function name="letex:quote-style-name" as="xsd:string">
<xsl:param name="style-name" as="xsd:string" />
<xsl:sequence select="string-join(
for $i in (1 to string-length($style-name))
return
if (not(matches(substring($style-name, $i, 1), '\w'))) then
concat(
'_',
replace(
substring(lower-case(string(
saxon:string-to-hexBinary(
substring($style-name, $i, 1),
'UTF16'
))),
5
),
'^0+',
''
),
'_'
)
else substring($style-name, $i, 1)
, '')" />
</xsl:function>
<xsl:function name="letex:has-style" as="xsd:boolean">
<xsl:param name="node" as="node()" />
<xsl:param name="style-family" as="xsd:string" />
<xsl:param name="style-name" as="xsd:string" />
<xsl:sequence select="boolean($node/@text:style-name eq letex:quote-style-name($style-name))" />
</xsl:function>
<xsl:function name="letex:satisfies-heading-markup" as="xsd:boolean">
<xsl:param name="node" as="node()" />
<xsl:param name="heading-markup" as="xsd:string" />
<xsl:sequence select="boolean($node/self::text:p[letex:has-style(., 'paragraph', $heading-markup)])" />
</xsl:function>
<xsl:function name="letex:topmost-heading-markup" as="xsd:string*">
<xsl:param name="nodes" as="node()*" />
<xsl:param name="heading-markup" as="xsd:string*" />
<xsl:choose>
<xsl:when test="count($heading-markup) eq 0">
<xsl:sequence select="()" />
</xsl:when>
<xsl:when test="some $n in $nodes satisfies (letex:satisfies-heading-markup($n, $heading-markup[1]))">
<xsl:sequence select="$heading-markup" />
</xsl:when>
<xsl:otherwise>
<xsl:sequence select="letex:topmost-heading-markup($nodes, $heading-markup[position() gt 1])" />
</xsl:otherwise>
</xsl:choose>
</xsl:function>
<!-- We don't need all this stuff if there are proper headings with outline-level attributes. -->
<!-- Case B: Outline levels are specified with the document's headings: -->
<xsl:function name="letex:hierarchize-by-outline" as="node()*">
<xsl:param name="nodes" as="node()*" />
<xsl:param name="outline-level" as="xsd:double*" />
<xsl:choose>
<xsl:when test="empty($outline-level)">
<xsl:sequence select="$nodes" />
</xsl:when>
<xsl:otherwise>
<xsl:for-each-group select="$nodes" group-starting-with="text:h[@text:outline-level = $outline-level]">
<xsl:choose>
<xsl:when test="current-group()[1]/@text:outline-level = $outline-level">
<xsl:text>
</xsl:text>
<div type="Heading_{$outline-level}">
<head>
<xsl:copy-of select="current-group()[1]/node()" />
</head>
<xsl:variable name="new-nodes" select="current-group()[position() gt 1]" as="node()*" />
<xsl:sequence select="letex:hierarchize-by-outline($new-nodes, min($new-nodes/@text:outline-level))" />
</div>
</xsl:when>
<xsl:otherwise>
<xsl:sequence select="letex:hierarchize-by-outline(current-group(), min(current-group()/@text:outline-level))" />
</xsl:otherwise>
</xsl:choose>
</xsl:for-each-group>
</xsl:otherwise>
</xsl:choose>
</xsl:function>
<!-- RESOLVE STYLES -->
<!-- collateral unicode normalization (convert to composed forms) -->
<xsl:template match="text()" mode="resolve-styles">
<xsl:value-of select="normalize-unicode(.)"/>
</xsl:template>
<xsl:template match="@text:style-name" mode="resolve-styles">
<xsl:choose>
<xsl:when test="(. = /office:document/office:styles/style:style/@style:name) or parent::text:list">
<xsl:attribute name="style-name" select="." />
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates select="/office:document/office:automatic-styles/style:style[@style:name = current()]" mode="resolve-style">
<xsl:with-param name="context" select=".." />
</xsl:apply-templates>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<!-- <xsl:template match="@style:style-name" mode="resolve-styles-details"> -->
<!-- <xsl:attribute name="loc" select="'st'" /> -->
<!-- <xsl:apply-templates select="/office:document/office:styles/style:style[@style:name = current()]" mode="resolve-style"/> -->
<!-- <xsl:attribute name="loc" select="'ed'" /> -->
<!-- </xsl:template> -->
<!-- <xsl:function name="resolve-style-absolutely" as="node()"> -->
<!-- <xsl:param name="text-elt" as="node()" /> -->
<!-- <xsl:param name="parent-text-elt" as="node()?" /> -->
<!-- <xsl:variable name="automatic-style" select="/office:document/office:automatic-styles/style:style[@style:name = current()]" /> -->
<!-- <xsl:variable name="parent-style" select="/office:document/office:styles/style:style[@style:name = $automatic-style/@parent-style]" /> -->
<!-- <xsl:variable name="automatic-style" select="/office:document/office:automatic-styles/style:style[@style:name = current()]" /> -->
<!-- </xsl:function> -->
<!-- please note the subtle difference between mode="resolve-styles" (catch-all) and resolve-style (local transformation) -->
<!-- Create attributes for *deviating* formatting: -->
<xsl:template match="office:automatic-styles/style:style" mode="resolve-style" as="attribute(*)*">
<xsl:param name="context" as="node()?" />
<xsl:variable name="parent-style" select="/office:document/office:styles/style:style[@style:name = current()/@style:parent-style-name]" />
<!-- BASE STYLE NAME: -->
<xsl:if test="@style:parent-style-name">
<xsl:attribute name="style-name" select="$parent-style/@style:name" />
</xsl:if>
<!-- If we are in a span: which paragraph style is in use?
Precedence is: most significant: current declaration, then parent declaration, then paragraph style declaration -->
<!-- <xsl:message> -->
<!-- <hurz> -->
<!-- <xsl:apply-templates select="$context/../@text:style-name" mode="resolve-styles" /> -->
<!-- <\!-\- parent para's parent style's settings: -\-> -->
<!-- <xsl:apply-templates select="/office:document/office:styles/style:style[ -->
<!-- @style:name = /office:document/office:automatic-styles/style:style[ -->
<!-- @style:name = $context/../@text:style-name -->
<!-- ]/@style:parent-style-name -->
<!-- ]" mode="resolve-styles-details" /> -->
<!-- <xsl:value-of select="count(/office:document/office:styles/style:style[ -->
<!-- @style:name = /office:document/office:automatic-styles/style:style[ -->
<!-- @style:name = $context/../@text:style-name -->
<!-- ]/@style:parent-style-name -->
<!-- ])" /> -->
<!-- </hurz> -->
<!-- </xsl:message> -->
<!-- deviating ALIGNMENT -->
<xsl:for-each select="style:paragraph-properties/@fo:text-align[. ne 'start']">
<xsl:attribute name="align" select="." />
</xsl:for-each>
<!-- deviating BORDER -->
<xsl:for-each select="style:paragraph-properties/@*[starts-with(name(), 'fo:border') and . ne 'none']">
<xsl:attribute name="{replace(name(), 'fo:', '')}" select="." />
</xsl:for-each>
<!-- deviating GENERIC FONT FAMILY -->
<xsl:if test="style:text-properties/@style:font-name">
<xsl:variable name="font-family-generic"
select="/office:document/office:font-face-decls/style:font-face[
@style:name = current()/style:text-properties/@style:font-name
]/@style:font-family-generic" />
<xsl:variable name="parent-font-family-generic"
select="/office:document/office:font-face-decls/style:font-face[
@style:name = letex:lookup-text-style($parent-style, 'font-name')
]/@style:font-family-generic" />
<xsl:if test="$font-family-generic ne $parent-font-family-generic">
<xsl:attribute name="font-family-generic" select="$font-family-generic" />
</xsl:if>
</xsl:if>
<!-- deviating FONT WEIGHT -->
<xsl:if test="style:text-properties/@fo:font-weight">
<xsl:attribute name="font-weight" select="style:text-properties/@fo:font-weight" />
</xsl:if>
<!-- deviating FONT STYLE -->
<xsl:if test="style:text-properties/@fo:font-style">
<xsl:attribute name="font-style" select="style:text-properties/@fo:font-style" />
</xsl:if>
<!-- deviating LETTER SPACING -->
<xsl:if test="style:text-properties/@fo:letter-spacing and (style:text-properties/@fo:letter-spacing ne 'normal')">
<xsl:attribute name="letter-spacing"
select="if (starts-with(style:text-properties/@fo:letter-spacing, '-')) then 'narrow' else 'wide'" />
</xsl:if>
<!-- deviating SUB-/SUPERSCRIPT -->
<xsl:if test="style:text-properties/@style:text-position and (style:text-properties/@style:text-position ne '0% 100%')">
<xsl:variable name="pos" select="replace(style:text-properties/@style:text-position, ' .+$', '')" />
<!-- <xsl:variable name="size" select="replace(style:text-properties/@style:text-position, '^.+ ', '')" /> -->
<xsl:if test="$pos ne '0%'">
<xsl:attribute name="position" select="if ($pos = 'sub' or starts-with($pos, '-')) then 'sub' else 'sup'" />
</xsl:if>
</xsl:if>
</xsl:template>
<xsl:function name="letex:lookup-text-style" as="xsd:string?">
<xsl:param name="style-node" as="node()?" />
<xsl:param name="style-property" as="xsd:string" />
<xsl:variable name="this-styles-value" select="$style-node/style:text-properties/@*[local-name() = $style-property]" as="xsd:string?" />
<xsl:choose>
<xsl:when test="boolean($this-styles-value)">
<xsl:sequence select="$this-styles-value" />
</xsl:when>
<xsl:otherwise>
<xsl:variable name="parent-style" select="root($style-node)/office:document/office:styles/style:style[@style:name = $style-node/@style:parent-style-name]" as="node()?"/>
<xsl:choose>
<xsl:when test="boolean($parent-style)">
<xsl:sequence select="letex:lookup-text-style($parent-style, $style-property)" />
</xsl:when>
<xsl:otherwise>
<xsl:sequence select="root($style-node)/office:document/office:styles/style:default-style[@style:family = $style-node/@style:family]/style:text-properties/@*[local-name() = $style-property]"/>
</xsl:otherwise>
</xsl:choose>
</xsl:otherwise>
</xsl:choose>
</xsl:function>
<!-- TRACK CHANGES markup -->
<xsl:function name="letex:tc-action" as="xsd:string">
<xsl:param name="change-start-or-end-node" as="node()" />
<xsl:value-of select="$change-start-or-end-node/ancestor::office:text/text:tracked-changes/text:changed-region[@text:id = $change-start-or-end-node/@text:change-id]/*/local-name()" />
</xsl:function>
<xsl:function name="letex:is-deleted" as="xsd:boolean">
<xsl:param name="node" as="node()" />
<xsl:variable name="bool-seq" as="xsd:boolean*">
<xsl:for-each select="$node/ancestor::office:text/text:tracked-changes/text:changed-region[text:deletion]/@text:id">
<xsl:variable name="change-start" select="$node/ancestor::office:text//text:change-start[@text:change-id = current()]" />
<xsl:variable name="change-end" select="$node/ancestor::office:text//text:change-end[@text:change-id = current()]" />
<xsl:variable name="is-between" select="$node >> $change-start and $node << $change-end" as="xsd:boolean"/>
<xsl:value-of select="$is-between"/>
</xsl:for-each>
</xsl:variable>
<xsl:value-of select="$bool-seq = true()" />
</xsl:function>
<!-- INCOMPLETE: We don't carry out paragraph merges yet! -->
<xsl:template match="*[letex:is-deleted(.)]" mode="resolve-styles" priority="1000"/>
<xsl:template match="text:change-start | text:change-end | text:tracked-changes" mode="resolve-styles" />
<!-- GROUP (NEST) STYLES -->
<xsl:template match="*[text:span[@* and not(@processed)]]" mode="group-styles">
<xsl:sequence select="letex:group-spans(., distinct-values(for $s in text:span[@* and not(@processed)] return letex:attr-hashes($s)))" />
</xsl:template>
<xsl:template match="@processed" mode="clean-group-styles" />
<xsl:template match="text:span[not(@*)]" mode="clean-group-styles">
<xsl:apply-templates mode="#current" />
</xsl:template>
<xsl:template match="text:span[@*] | text:p[@*]" mode="clean-group-styles">
<xsl:copy>
<xsl:copy-of select="@style-name except @style-name[. = ('Footnote')]" />
<xsl:variable name="rend" select="string-join(for $a in (@* except (@processed union @style-name)) return letex:rend($a), ' ')" />
<xsl:if test="$rend ne ''">
<xsl:attribute name="rend" select="$rend" />
</xsl:if>
<xsl:apply-templates mode="#current" />
</xsl:copy>
</xsl:template>
<xsl:function name="letex:rend" as="xsd:string?">
<xsl:param name="attr" as="attribute(*)" />
<xsl:choose>
<xsl:when test="name($attr) = 'border'">
<xsl:choose>
<xsl:when test="$attr = 'none'" />
<xsl:otherwise>border</xsl:otherwise>
</xsl:choose>
</xsl:when>
<xsl:when test="name($attr) = 'font-family-generic'">
<xsl:choose>
<xsl:when test="$attr = 'modern'">typewriter</xsl:when>
</xsl:choose>
</xsl:when>
<xsl:when test="name($attr) = 'font-style'">
<xsl:choose>
<xsl:when test="$attr = 'normal'">style-normal</xsl:when>
<xsl:otherwise><xsl:value-of select="$attr"/></xsl:otherwise>
</xsl:choose>
</xsl:when>
<xsl:when test="name($attr) = 'font-weight'">
<xsl:choose>
<xsl:when test="$attr = 'normal'">weight-normal</xsl:when>
<xsl:otherwise><xsl:value-of select="$attr"/></xsl:otherwise>
</xsl:choose>
</xsl:when>
<xsl:otherwise>
<!-- <xsl:value-of select="string-join((name($attr), $attr), ': ')"/> -->
<xsl:value-of select="$attr"/>
</xsl:otherwise>
</xsl:choose>
</xsl:function>
<xsl:function name="letex:attr-hashes" as="xsd:string*">
<xsl:param name="node" as="node()?" />
<xsl:variable name="hashes" as="xsd:string*">
<xsl:for-each select="$node">
<xsl:call-template name="attr-hashes" />
</xsl:for-each>
</xsl:variable>
<xsl:sequence select="$hashes" />
</xsl:function>
<xsl:template name="attr-hashes">
<xsl:for-each select="attribute(*)[not(name() = 'processed')]">
<xsl:value-of select="concat(name(current()), '__', .)" />
</xsl:for-each>
</xsl:template>
<xsl:function name="letex:attname" as="xsd:string">
<xsl:param name="hash" as="xsd:string" />
<xsl:value-of select="replace($hash, '__.+$', '')" />
</xsl:function>
<xsl:function name="letex:attval" as="xsd:string">
<xsl:param name="hash" as="xsd:string" />
<xsl:value-of select="replace($hash, '^.+__', '')" />
</xsl:function>
<xsl:template match="@*" mode="test">
<xsl:attribute name="hash" select="letex:attr-hashes(..)" />
</xsl:template>
<xsl:template match="text:span" mode="test">
<span>
<xsl:apply-templates select="@*|node()" mode="#current" />
</span>
</xsl:template>
<xsl:function name="letex:group-spans" as="node()*">
<xsl:param name="parent-node" as="node()" />
<xsl:param name="properties" as="xsd:string*" />
<xsl:variable name="nesting" as="node()*">
<xsl:element name="{name($parent-node)}">
<xsl:copy-of select="$parent-node/@*" />
<xsl:choose>
<xsl:when test="count($properties) gt 0">
<xsl:for-each-group select="$parent-node/node()" group-adjacent="boolean($properties[1] = letex:attr-hashes(.))">
<!-- <xsl:message> -->
<!-- Prop: <xsl:value-of select="$properties[1]"/> -->
<!-- Group: -->
<!-- <xsl:apply-templates select="current-group()" mode="test"/> -->
<!-- </xsl:message> -->
<xsl:choose>
<xsl:when test="$properties[1] = letex:attr-hashes(current-group()[1]/self::text:span)">
<xsl:variable name="common-properties" select="$properties[every $s in current-group() satisfies (. = letex:attr-hashes($s))]"/>
<text:span processed="true">
<xsl:for-each select="$common-properties">
<xsl:attribute name="{letex:attname(current())}" select="letex:attval(current())" />
</xsl:for-each>
<xsl:apply-templates select="current-group()" mode="exclude">
<xsl:with-param name="exclude-properties" select="$common-properties" />
</xsl:apply-templates>
</text:span>
</xsl:when>
<xsl:otherwise>
<xsl:copy-of select="current-group()" />
</xsl:otherwise>
</xsl:choose>
</xsl:for-each-group>
</xsl:when>
<xsl:otherwise>
<xsl:copy-of select="$parent-node/node()" />
</xsl:otherwise>
</xsl:choose>
</xsl:element>
</xsl:variable>
<xsl:choose>
<xsl:when test="every $s in $nesting/text:span satisfies $s/@processed">
<xsl:copy-of select="$nesting"/>
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates select="$nesting" mode="group-styles" />
</xsl:otherwise>
</xsl:choose>
</xsl:function>
<xsl:template match="text:span" mode="exclude">
<xsl:param name="exclude-properties" as="xsd:string+" />
<xsl:copy>
<xsl:copy-of select="@* except @*[max(for $x in $exclude-properties return boolean(name() = letex:attname($x) and (. = letex:attval($x))))]" />
<xsl:apply-templates mode="#current">
<xsl:with-param name="exclude-properties" select="$exclude-properties" />
</xsl:apply-templates>
</xsl:copy>
</xsl:template>
<xsl:template match="text:sequence-decls" mode="resolve-styles" />
<xsl:template match="text:soft-page-break" mode="resolve-styles" />
<!-- <xsl:template match="text:line-break" mode="resolve-styles"><lb /></xsl:template> -->
<xsl:template match="text:s" mode="resolve-styles">
<xsl:text> </xsl:text>
</xsl:template>
<!-- mode="main" -->
<xsl:template match="text:note[@text:note-class='footnote']" mode="main">
<note xml:id="{@text:id}" type="footnote">
<xsl:if test="text:note-citation">
<xsl:attribute name="n" select="text:note-citation" />
</xsl:if>
<xsl:apply-templates mode="#current" />
</note>
</xsl:template>
<xsl:template match="text:note[@text:note-class='footnote']/text:note-citation" mode="main" />
<xsl:template match="text:note-body" mode="main">
<xsl:apply-templates mode="#current" />
</xsl:template>
<xsl:template match="text:p[@style-name = 'Quotations']" mode="main" priority="2">
<quote>
<xsl:copy-of select="@* except @style-name" />
<xsl:apply-templates mode="#current" />
</quote>
</xsl:template>
<xsl:template match="text:p" mode="main">
<p>
<xsl:call-template name="paragraph-attributes"/>
<xsl:apply-templates mode="#current" />
</p>
</xsl:template>
<xsl:template name="paragraph-attributes">
<xsl:copy-of select="@* except @style-name" />
<xsl:if test="@style-name[. ne 'Standard'] and not(@rend)">
<xsl:attribute name="rend" select="@style-name" />
</xsl:if>
</xsl:template>
<xsl:template match="text:p[matches(letex:rendered-content(.), '^\s*―\s*$')]" mode="main">
<milestone unit="section" type="dash" />
<xsl:call-template name="process-annotations" />
</xsl:template>
<xsl:template match="text:p[matches(letex:rendered-content(.), '^\s*\*{3,6}\s*$')]" mode="main">
<milestone unit="section" type="asterisks" />
<xsl:call-template name="process-annotations" />
</xsl:template>
<xsl:template name="process-annotations">
<xsl:apply-templates select="office:annotation" mode="#current" />
</xsl:template>
<xsl:template match="text:p[text:sequence/@text:name]" mode="main" priority="50" />
<xsl:template match="text:p[text:sequence/@text:name]" mode="caption">
<head>
<xsl:apply-templates mode="#current" />
</head>
</xsl:template>
<xsl:template match="text:spanX" mode="main">
<xsl:variable name="mapped-style" select="letex:map-style('seg', 'style-name', @style-name)" />
<xsl:choose>
<xsl:when test="boolean($mapped-style)">
<seg type="{$mapped-style}">
<xsl:apply-templates mode="#current" />
</seg>
</xsl:when>
<xsl:otherwise>
<seg>
<xsl:copy-of select="@* except (@style-name union @processed)" />
<xsl:apply-templates mode="#current" />
</seg>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="text:span[@*]" mode="main">
<hi>
<xsl:apply-templates select="@*" mode="#current" />
<xsl:apply-templates mode="#current" />
</hi>
</xsl:template>
<xsl:template match="text:span[@style-name='Emphasis']" mode="main" priority="2">
<emph rend="italics">
<xsl:apply-templates select="@* except @style-name" mode="#current" />
<xsl:apply-templates mode="#current" />
</emph>
</xsl:template>
<xsl:template match="text:a[@xlink:href]" mode="main">
<ref target="{@xlink:href}">
<xsl:apply-templates mode="#current" />
</ref>
</xsl:template>
<xsl:template match="office:annotation" mode="main">
<note type="internal"><xsl:apply-templates select="* except (dc:creator union dc:date)" mode="#current" />
(<name><xsl:value-of select="dc:creator"/></name><!--<date when-iso="{dc:date}"/>-->)
</note>
</xsl:template>
<!-- Utility function to determine the actually rendered content of an element (modulo note text, etc.) -->
<xsl:function name="letex:rendered-content" as="xsd:string?">
<xsl:param name="node" as="node()" />
<xsl:variable name="strings" as="xsd:string*">
<xsl:apply-templates select="$node" mode="rendered-content" />
</xsl:variable>
<xsl:value-of select="string-join($strings, '')"/>
</xsl:function>
<!-- list maybe incomplete: -->
<xsl:template match="text:p | text:h | text:span |
tei:p | tei:seg | tei:div | tei:l | tei:hi | tei:emph | tei:head" mode="rendered-content">
<xsl:apply-templates mode="#current" />
</xsl:template>
<xsl:template match="text:note" mode="rendered-content">
<xsl:value-of select="note-citation" />
</xsl:template>
<xsl:template match="*" mode="rendered-content" priority="-0.5" />
<!-- VERSE -->
<xsl:template match="text:p[@style-name='Verse']" mode="verse">
<lg type="verse">
<xsl:for-each-group select="node()" group-starting-with="text:line-break">
<l>
<xsl:apply-templates select="current-group() except self::text:line-break" mode="#current"/>
</l>
</xsl:for-each-group>
</lg>
</xsl:template>
<xsl:template match="*[text:p[@style-name='Verse']]" mode="verse">
<xsl:copy>
<xsl:copy-of select="@*" />
<xsl:for-each-group select="node()" group-adjacent="boolean(self::text:p[@style-name='Verse'])">
<xsl:choose>
<xsl:when test="current-grouping-key()">
<xsl:text>
</xsl:text>
<div type="verse">
<xsl:copy-of select="current-group()[1]/@rend" />
<xsl:apply-templates select="current-group()" mode="#current" />
</div>
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates select="current-group()" mode="#current" />
</xsl:otherwise>
</xsl:choose>
</xsl:for-each-group>
</xsl:copy>
</xsl:template>
<!-- LETTERs -->
<xsl:template match="*[text:p[@style-name='Opener']]" mode="letter">
<xsl:copy>
<xsl:copy-of select="@*" />
<xsl:for-each-group select="node()" group-starting-with="text:p[@style-name = 'Opener']">
<xsl:choose>
<xsl:when test="current-group()[1][@style-name='Opener']">
<xsl:text>
</xsl:text>
<div type="letter">
<xsl:apply-templates select="current-group()
except
current-group()[. >> current-group()/self::text:p[@style-name = 'Salutation']]"
mode="#current" />
</div>
<xsl:apply-templates select="current-group()[. >> current-group()/self::text:p[@style-name = 'Salutation']]"
mode="#current" />
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates select="current-group()" mode="#current" />
</xsl:otherwise>
</xsl:choose>
</xsl:for-each-group>
</xsl:copy>
</xsl:template>
<xsl:template match="text:p[@style-name = 'Opener']" mode="letter">
<xsl:text>
</xsl:text>
<opener>
<xsl:apply-templates select="@* except @style-name | node()" mode="#current" />
</opener>
</xsl:template>
<xsl:template match="text:p[@style-name = 'Salutation' and matches(., '^\s*$')]" mode="letter" />
<xsl:template match="text:p[@style-name = 'Salutation' and not(matches(., '^\s*$'))]" mode="letter">
<closer>
<xsl:apply-templates select="@* except @style-name | node()" mode="#current" />
</closer>
</xsl:template>
<!-- TABLES -->
<xsl:template match="table:table" mode="main">
<xsl:choose>
<xsl:when test="matches( @table:style-name, '[Gg]lossar(tabelle)?' )">
<list type="gloss">
<!--<head/>-->
<xsl:apply-templates mode="gloss"/>