build.gradle

plugins {
    id 'java-library'
    id 'groovy'
    id "com.jfrog.bintray" version "1.8.3"
}

apply plugin: 'maven-publish'


dependencies {
    api 'org.spockframework:spock-core:1.1-groovy-2.4'
    api 'com.github.tomakehurst:wiremock:2.16.0'
    implementation 'com.google.guava:guava:23.0'
    testImplementation 'org.codehaus.groovy:groovy-all:2.4.13'
    testImplementation "org.apache.httpcomponents:httpclient:4.5.5"
}

repositories {
    jcenter()
}

version = '0.1.12'

jar {
    manifest {
        attributes('Implementation-Title': project.name,
                'Implementation-Version': project.version)
    }
}

ext.artifactBaseName = 'spock-wiremock-extension'


task sourcesJar(type: Jar) {
    baseName artifactBaseName
    classifier 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

artifacts {
    archives sourcesJar
    archives javadocJar
}

publishing {
    publications {
        MyPublication(MavenPublication) {
            from components.java
            groupId 'com.felipefdzdz.spock'
            artifactId 'spock-wiremock-extension'
            version '0.1.12'

            artifact sourcesJar
            artifact javadocJar
        }
    }
}

bintray {
    user = System.getenv('BINTRAY_USER')
    key = System.getenv('BINTRAY_KEY')
    pkg {
        repo = 'spock-wiremock-extension'
        name = 'spock-wiremock-extension'
        userOrg = 'felipefzdz'
        licenses = ['Apache-2.0']
        vcsUrl = 'https://github.com/felipefzdz/spock-wiremock-extension.git'
        version {
            name = '0.1.12'

        }
        publications = ['MyPublication']
    }
}